framboise314.fr

Code : Tout sélectionner

//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Version pour ESP8266  - DEEP Batterie DEEP
// Version du 17/09/2021
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
#define DEBUG
#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
#include <ESP8266HTTPClient.h>
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Version
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
String script = "SHT3XDeep-5.101";
String host = "ESP-02";
String dest = "";
String dest1 = "http://192.168.A.X";
String dest2 = "http://192.168.B.Y";
String sondes = "SHT31";
String type = "Deep";
String Alim = "Accus";
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Variables SHT
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
#include "Wire.h"
#include "SHT31.h"
SHT31 sht;
float t = 0;
float h = 0;
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Timers
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
#define INTERVAL	  	118 	  	// 120 secondes
#define NB_TRYWIFI	 10 		// nbr d'essai connexion WiFi, number of try to connect WiFi
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Variables WiFi
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
String ssid1 = "SSID_A";
String psk1 = "PassPhrase_A";
String ssid2 = "SSID_B";
String psk2 = "PassPhrase_B";
ESP8266WiFiMulti wifiMulti;
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Procedure Connexion
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
void connexion()
{
  wifiMulti.addAP(ssid1.c_str(), psk1.c_str());
  wifiMulti.addAP(ssid2.c_str(), psk2.c_str());
#ifdef DEBUG
  Serial.println("Connexion Wifi...");
#endif
  int _try = 0;
  while (wifiMulti.run() != WL_CONNECTED)
  {
#ifdef DEBUG
    Serial.print("#");
#endif
    delay(500);
    _try++;
    if ( _try >= NB_TRYWIFI )
    {
#ifdef DEBUG
      Serial.println("Impossible to connect WiFi network, go to deep sleep");
#endif
      ESP.deepSleep(10 * 1000000);
    }
  }
  if ( WiFi.SSID() == ssid1)
    dest = dest1;
  else if ( WiFi.SSID() == ssid2)
    dest = dest2;
}
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
// Evoie des données
//-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
int Send(String URL)
{
  WiFiClient client;
  HTTPClient http;
  int OK = 0;
  if (http.begin(URL))
  {
    int httpCode = http.GET();
    OK = httpCode;
#ifdef DEBUG
    if (httpCode > 0)
    {
      Serial.printf("[HTTP] GET... code: %d\n", httpCode);
      if (httpCode == HTTP_CODE_OK || httpCode == HTTP_CODE_MOVED_PERMANENTLY)
      {
        String payload = http.getString();
        Serial.println(payload);
      }
    }
    else
    {
      Serial.printf("[HTTP] GET... failed, error: %s\n", http.errorToString(httpCode).c_str());
    }
#endif
    http.end();
  }
  return OK;
}
//===========================================================================
//  SETUP
//===========================================================================
void setup()
{
  Serial.begin(115200);
  WiFi.persistent(false);
  WiFi.mode(WIFI_STA);
  WiFi.hostname(host);
  connexion();
#ifdef DEBUG
  Serial.println("Connected to the WiFi network");
  Serial.print ( "IP address: " );
  Serial.println ( WiFi.localIP() );
#endif
  Wire.begin();
  sht.begin(0x44);
  Wire.setClock(100000);
  sht.read();
  float ts = sht.getTemperature();
  float hs = sht.getHumidity();
  String url = dest;
  url += "/meteo/php/logdeep.php?Host=";
  url += host;
  url += "&Sondes=";
  url += sondes;
  url += "&Alim=";
  url += Alim;
  url += "&Script=";
  url += script;
  url += "&SSID=";
  url += WiFi.SSID();
  url += "&Signal=";
  url += WiFi.RSSI();
  url += "&IP=";
  url += WiFi.localIP().toString();
  url += "&Tmp=";
  url += ts;
  url += "&Hum=";
  url += hs;
  int rep = Send(url);
#ifdef DEBUG
  Serial.println(url);
  Serial.println(rep);
#endif
  if (rep == 200)
  {
    ESP.deepSleep(INTERVAL * 1000000);
  }
  else
  {
    delay(2000);
    ESP.restart();
  }
}
//===========================================================================
//  Boucle Principale
//===========================================================================
void loop() {
}